Scoprire i viaggi letterari con il catalogo CoBiS LOD

Negli ultimi anni grande è stato l’impegno accademico nello studio di contenuti letterari che avessero come tema centrale il viaggio come esperienza che completasse in modo concreto l’attività di formazione.

Il viaggio, inteso in senso culturale, è stato documentato da studiosi sia di natura umanistica sia scientifica ed è diventato nel tempo occasione necessaria come fonte di ispirazione, convergenza di culture e scambi di idee tra intellettuali. 

L’Italia, ad esempio, è stata meta molto ambita durante gli anni del fenomeno socio-culturale del Grand Tour.

I racconti prodotti in quegli anni si conservano sotto forma di appunti su diari e taccuini, libri, guide, disegni, mappe dei territori e non solo conservano tracce storiche, ma rappresentano una testimonianza diretta della società, degli usi e dei costumi del tempo.

Infatti, lo studio di queste memorie non solo consente un arricchimento dei dati storici, scientifici, artistici e letterari, ma anche di mappare i cambiamenti di un determinato territorio e tracciare come lo stile di vita muti nel tempo.

Il RuenzoriLe biblioteche, come pure archivi e musei, conservano libri e racconti dei viaggiatori, intese come testimonianze dirette da analizzare, e questo articolo intende fornire un approccio e strumenti di studio diversi per affrontare una ricerca sul tema.

Alcuni di questi documenti sono già disponibili in versione digitale, ma esistono anche numerosi documenti solo cartacei, raggiungibili attraverso i dati catalografici della biblioteca che li possiede.

Nel nostro caso specifico, quali opere si trovano sul catalogo del CoBiS a riguardo?

Scopriamolo attraverso il punto di accesso SPARQL del CoBiS.

Proviamo a cercarle impostando una query SPARQL che restituisca tra i risultati tutte le opere con digitalizzazione (utilizzando la proprietà foaf:depiction) nel cui titolo è presente la parola “viaggio” (inserendo FILTER e CONTAINS per individuare le keyword fornite) come segue:

SELECT distinct ?instance ?name ?ia

WHERE {

?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

?instance foaf:depiction ?ia .

?instance schema:name ?name .

}

ORDER BY ?name

Vai al risultato.

Oppure, specificare di includere le opere in cui le parole “viaggio” o “memorie” risultano essere argomento principale (utilizzando la proprietà bf2:subject):

SELECT distinct  ?instance ?name ?subject

WHERE {

?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

OPTIONAL {?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))}

OPTIONAL {?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

}

Order by desc (?name)

Vai al risultato.

Per filtrare solamente quali tra queste opere hanno le parole “viaggio” o “memorie” come argomento principale:

SELECT distinct  ?instance ?name ?subject

WHERE {

?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

{?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))} UNION { ?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

}

Order by desc (?name)

Vai al risultato.

Se, invece, volessimo visualizzare anche la data di pubblicazione va aggiunta la proprietà cobis:dataNormalizzata:

SELECT distinct  ?instance ?name ?subject ?date

WHERE {

?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

{?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))} UNION { ?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

?instance cobis:dataNormalizzata ?date .

}

Order by desc (?name)

Vai al risultato.

Per scoprire la lingua dell’opera basta inserire una tripla con la proprietà bf2:language:

SELECT distinct  ?instance ?name ?subject ?date ?language

WHERE {
?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

{?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))} UNION { ?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

OPTIONAL {?instance cobis:dataNormalizzata ?date .}

OPTIONAL{?instance bf2:language ?language .}

Vai al risultato.

Invece, aggiungere schema:author permette di conoscere l’autore:

SELECT distinct  ?instance ?name ?subject ?date ?language ?agent ?contributor

WHERE {
?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

{?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))} UNION { ?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

OPTIONAL {?instance cobis:dataNormalizzata ?date .}

OPTIONAL{?instance bf2:language ?language .}

OPTIONAL{?instance schema:author ?agent .}

OPTIONAL{?instance schema:contributor ?contributor .}

}

Vai al risultato.

Se volessimo sapere in quale biblioteca si trovano le opere:

SELECT distinct  ?instance ?name ?subject ?date ?language ?agent ?contributor ?library ?label

WHERE {

?instance schema:name ?name . 

FILTER (CONTAINS(?name, "viaggio"))

{?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "viaggi"))} UNION { ?instance bf2:subject ?subject .

FILTER (CONTAINS(?subject, "memorie"))}

OPTIONAL {?instance cobis:dataNormalizzata ?date .}

OPTIONAL{?instance bf2:language ?language .}

OPTIONAL{?instance schema:author ?agent .}

OPTIONAL{?instance schema:contributor ?contributor .}

?instance bf2:hasItem ?item .

?item bf2:heldBy ?library .
?library rdfs:label ?label .
}

Vai al risultato.

Come si possono scoprire le tappe più gettonate? Dove hanno studiato gli autori di queste opere? C’è convergenza con i luoghi di cui hanno scritto o luoghi di studio?

Queste sono informazioni che è possibile scoprire con una ricerca incrociata tra due database: interrogando allo stesso tempo i dati della base di conoscenza disponibile online e collegata alla linked open data cloud Wikidata, che conserva dati biografici e geografici strutturati sugli autori, e il catalogo LOD del CoBiS.

Cos’è Wikidata e come sono integrati i dati con il catalogo del CoBiS

Si tratta di una base di conoscenza libera, aperta, collaborativa e multilingue che si arricchisce di dati strutturati grazie al contributo della community.

WikidataSulla piattaforma tutte le entità sono raggiungibili tramite un URL e identificate in modo univoco attraverso un codice identificativo; nel caso degli autori del CoBiS LOD è stata creata una proprietà specifica che afferma un’equivalenza tra i l’ID Wikidata di un autore e l’identificativo degli autori del catalogo, mettendo i dati in relazione.

Attraverso l’ID avviene l’integrazione dei dati biografici degli autori sul catalogo LOD, ma è possibile anche interrogare direttamente la piattaforma impostando query specifiche con il linguaggio di interrogazione SPARQL.

Che risultati si possono ottenere e come impostare la query

Come per i dati CoBiS, anche per descrivere i dati su Wikidata si fa riferimento a un’ontologia condivisa e stabilita dalla community.

Rispetto a quanto esposto nell’articolo sulle ontologie, nel linguaggio di interrogazione utilizzato la struttura è la stessa, a cambiare in questo caso sono i termini dei concetti espressi, vari in base alle esigenze descrittive delle entità, e la loro forma; infatti, le proprietà e le entità vengono identificate attraverso una lettera, P per le proprietà e Q per le entità, seguita da numeri.

Per approfondire la ricerca incrociando i dati del catalogo CoBiS con i dati di Wikidata, attraverso il codice identificativo degli autori, ad esempio è possibile cercare i luoghi in cui le opere sono ambientate nel modo seguente:

SELECT distinct ?item ?itemLabel ?author ?authorLabel ?data ?argomentoLabel ?id_archive ?wikisource ?wikipedia

WHERE {

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

  ?item wdt:P50 ?author .

  ?author wdt:P7865 ?identificativo_CoBiS_di_un_autore .

  { ?item wdt:P136 wd:Q1072723. }

  UNION

  { ?item wdt:P136 wd:Q1164267. }

  ?item wdt:P921 ?argomento.

  ?item wdt:P577 ?data.

  OPTIONAL {?item wdt:P724 ?id_archive .}

  OPTIONAL {?wikisource schema:about ?item ;

schema:isPartOf <https://it.wikisource.org/> .}

  OPTIONAL {?wikipedia schema:about ?item ;

schema:isPartOf <https://it.wikipedia.org/> .}

}

Vai al risultato.


Per comprendere il vantaggio dell’interoperabilità, sono disponibili di seguito altre query che è possibile impostare per visualizzare i dati sotto forma di mappe, grafici o timeline:

E tu che tema sceglieresti? Prova anche tu a interrogare il catalogo LOD attraverso il punto d’accesso SPARQL.

Per scoprire altre curiosità continuate a seguire il sito del CoBiS per ulteriori approfondimenti e i canali social.